/*****************************************************************************\
 *              Create.cmd  creates icons for applications included          *
 *                with the Internet Access Kit in the BonusPak               *
 *                                                                           *
 *          The difference with the 'standard' icons you already have        *
 *          is that these icons do not start LINKUP.EXE (which makes         *
 *         sure that the SLIP/PPP link has been established) before the      *
 *         application is started. Create.cmd was made by Jacco de Leeuw     *
\*****************************************************************************/

/* load rexx utility functions */
Call RxFuncAdd 'SysLoadFuncs', 'RexxUtil', 'SysLoadFuncs'
Call SysLoadFuncs

crlf='0d0a'x;
TCPapp.1=9;
TCPapp.2.1= "gopher.exe"; 	TCPapp.2.2=""; TCPapp.2.3="Gopher";
TCPapp.3.1= "nr2.exe";		TCPapp.3.2=""; TCPapp.3.3="NewsReader/2";
TCPapp.4.1= "explore.exe";	TCPapp.4.2=""; TCPapp.4.3="WebExplorer";
TCPapp.5.1= "telnetpm.exe";	TCPapp.5.2=""; TCPapp.5.3="Telnet";
TCPapp.6.1= "ftppm.exe";	TCPapp.6.2=""; TCPapp.6.3="FTP-PM";
TCPapp.7.1= "pmant.exe";	TCPapp.7.2=""; TCPapp.7.3="3270 Telnet";
TCPapp.8.1= "archie.exe";	TCPapp.8.2=""; TCPapp.8.3="Archie";
TCPapp.9.1= "update.exe";	TCPapp.9.2="/h updates.gopher.ibm.com"; TCPapp.9.3="Retrieve"crlf"Software Updates";

Say crlf'FreeTCP';
Say '-------'
Say 'This REXX script creates icons which do NOT call LINKUP.EXE for most of';
Say 'the applications included with the Internet Access Kit in the BonusPak.'crlf;
Say 'Creating folder "Internet applications for the LAN".'crlf;
classname = 'WPFolder';
location = '<WP_DESKTOP>';
setup = 'OBJECTID=<FreeTCP_Folder>;OPEN=DEFAULT;';
title= 'Internet applications'crlf'for the LAN';
result=SysCreateObject(classname,title,location,setup,f);

Do i = 2 to TCPapp.1
	filespec = SysSearchPath('PATH',TCPapp.i.1);
	If filespec = '' Then
		Say 'Not found: 'TCPapp.i.1' 'TCPapp.i.2;	
	Else Do
		classname = 'WPProgram';
		location = '<FreeTCP_Folder>';
		setup = 'EXENAME='TCPapp.i.1';PARAMETERS='TCPapp.i.2';';
		title = TCPapp.i.3;
		Say 'Creating icon for: 'TCPapp.i.1' 'TCPapp.i.2;
		Call SysCreateObject classname,title,location,setup,u;
	End
End;
Exit;